vb.net 教程 5-14 图像处理之内存处理基础4- VB

版权声明：本文为博主原创文章，转载请在显著位置标明本文出处以及作者网名，未经作者允许不得用于商业目的。
之前讲了这么多内容，这篇将把之前的理论运用到实际中。

准备工作：新建一个窗体，放两个按钮，分别的Text属性为“载入图片”和“一维数组”，如下图：

因为我们会使用到BitmapData类和Marshal类，

所以需要添加两个引用：

Imports System.Drawing.Imaging
Imports System.Runtime.InteropServices

“载入图片”的代码和窗体载入时候的代码，请参看之前图像处理之像素处理的代码。

按下“一维数组”后的代码如下：

'内存转一维数组处理代码
Private Sub Button4_Click(sender As Object, e As EventArgs) Handles Button4.Click
'定义目标图片
Dim destImg As New Bitmap(sourceImg.Width, sourceImg.Height)
'定义源BitmapData,锁定区域是整个图片，只需要读取模式，采用24位RGB
Dim sourceData As BitmapData = sourceImg.LockBits(New Rectangle(0, 0, sourceImg.Width, sourceImg.Height), ImageLockMode.ReadOnly, PixelFormat.Format24bppRgb)
'定义目标BitmapData,锁定区域是整个图片，只需要写入模式，采用24位RGB
Dim destData As BitmapData = destImg.LockBits(New Rectangle(0, 0, sourceImg.Width, sourceImg.Height), ImageLockMode.WriteOnly, PixelFormat.Format24bppRgb)
'获得源BitmapData的起始指针位置
Dim pSource As IntPtr = sourceData.Scan0
'获得源BitmapData占用内存空间的总的字节数
Dim allBytes As Integer = sourceData.Stride * sourceData.Height
'定义数组，用来放置源BitmapData的数据
Dim rgbvalues() As Byte
ReDim rgbvalues(allBytes - 1)
'把指针位置开始allBytes个字节数据拷贝到rgbvalues()数组中
Marshal.Copy(pSource, rgbvalues, 0, allBytes)

'数组中第一个字节的序号
Dim pos As Integer = 0
Dim R, G, B As Integer
Dim avgValue As Integer

'先高度，后宽度
For j As Integer = 0 To sourceData.Height - 1
For i As Integer = 0 To sourceData.Width - 1
'图片上(i,j)像素对应的蓝色分量值
B = rgbvalues(pos)
'图片上(i,j)像素对应的蓝色分量值
G = rgbvalues(pos + 1)
'图片上(i,j)像素对应的蓝色分量值
R = rgbvalues(pos + 2)
'这里使用的是均值法
avgValue = (B + G + R) / 3
'把求出的数据写回去
rgbvalues(pos) = avgValue
rgbvalues(pos + 1) = avgValue
rgbvalues(pos + 2) = avgValue
'终归是在一维数组里面取数据，向前推进3个字节
pos = pos + 3
Next
'一行数据取完了，继续推进到下一行
pos = pos + sourceData.Stride - sourceData.Width * 3
Next

'获得目标BitmapData的起始指针位置
Dim pDest As IntPtr = destData.Scan0
'将数组的内容拷到pDest指针开始的内存
Marshal.Copy(rgbvalues, 0, pDest, allBytes)
'不要忘了解锁
sourceImg.UnlockBits(sourceData)
destImg.UnlockBits(destData)

picDest.Image = destImg

End Sub
我在代码中做了详细的解释，相信大家看代码和注释就可以看懂的。运行后的结果：